Обновление формата показа WEB ИРБИС64 fullwebr.pft
Пользователь:
Constantin (IP-адрес скрыт)
Дата: 02, July, 2013 15:41
Для ускорения работы шлюза 11 и 12 версии WEB ИРБИС64 рекомендуется заменить формат показа fullwebr.pft на следующий:
,'</>',
&uf('+1w8#',(if v3413<>'' then '&R21DBN=',v3413 else break fi)),
'<tr width=100%><td with=5% valign="top"><b><--MFNCOUNT-->.</b>',
'<span> <a title="~~Напечатать~~" href="<--CGI_PATH-->?LNG=',&uf('Av5500#1'),'&P21DBN=',&unifor('Av3331#1'),'&I21DBN=',S(&unifor('Av3331#1'),'_PRINT'),'&S21FMT=fullw_print&C21COM=F&Z21MFN=',f(val(MFN),0,0),'">',
'<img border=0 width=32 height=32 src="<--HTTP_PATH-->/images/printer.jpg">',
'</a></span>',
print_checkbox
'</td>',
&uf('+1W9953#'),
'<td width=95%>',
if 'img ft':v3600 then else
&uf('+1W9953#'&uf('6show_cover')),
if p(g9953) then '<img style="float:left; margin:10px; width:120px;" src="',g9953,'">' fi,
fi,
if v907^C:'ОБРНЗ' then if &unifor('IPRIVATE,ETR,')='obrzv' then else
'<DIV ALIGN=CENTER><b> ~~Издание в обработке. Не выдается~~<br> </b> <DIV ALIGN=LEFT>' fi fi,
if v3600<>'' then
if p(v953) then
&uf('6image'),
else
&uf('6fulltext'),
fi,
else
if v920.2:'NJ' then
&uf('6njw_H'),
else
if v920.1:'J'then ,
&uf('6jw_H'),
else
!!kk0shp_H,
!!kk1bo_W,
!!kk2udk_W,
orubdks_W,
!!kk4ann_W,
ed_reference,
Ofinal_W,
!!kw7ex,
fi,
fi ,
fi,
if &uf('IMAIN,GENERATION,')<>'32' and (not s(&uf('IMAIN,FULLTEXT_BASES,')):v3331) then
/* Слова найденные в тексте
if p(v3336) then '<div style="border:0px;font-size:xx-small;color:#999999">'/,'<a title="~~Слова найденные в документе в результате поиска с ранжированием~~">','<!>',v3336,'<!>','</a>'/,'</div>' fi,
MPL, same_search
fi,
go_to_articles,
order ,
download,
/*if &uf('IMAIN,GENERATION,')<>'32' and (not s(&uf('IMAIN,IMAGE_BASES,'),&uf('IMAIN,FULLTEXT_BASES,')):v3331) then
/* if p(v953) then '<img src="<--CGI_PATH-->?LNG=',&uf('Av5500#1'),'&C21COM=3&P21DBN=',v3331,'&I21DBN=',v3331,'&BINARY_RESOURCE_OCC=1&BINARY_RESOURCE_MFN=',f(val(MFN),0,0),'">', fi,
/*fi,
'<hr noshade size="1"></td></tr>',&unifor('!')
Редактировано 1 раз. Последний раз 03.07.2013 14:57 пользователем Constantin.