/* формат возвращает url обложки
/* g3 - получаем url обложки
/* g1 - вспомогательная переменная

&uf('+7W3#'),

if p(v953) then 
  (if p(v953) then 
    if v953^p='2' or 1=1 then                  
      &uf('+7W3#',
         &uf('IMAIN,PATHTOCGIIRBIS,'),'?LNG=&C21COM=3&P21DBN=',&uf('+D'),'&I21DBN=',&uf('+D'),'&BINARY_RESOURCE_OCC=1&BINARY_RESOURCE_MFN=',f(val(MFN),0,0),'&Z21ID=GUEST',
         ),
      break
    fi,                       
  fi)
fi,

if g3 = '' then
   if p(v951) and (v951:'^H02a' or v951:'^H02b') then 
      (if p(v951) then 
         if v951^h:'02' then 
            &uf('+7W1#',if p(v951^a) then v951^a else v951^i fi),

            if p(v951^a) or v951^I:':\' then                    

               &uf('+7W3#',&uf('IMAIN,PATHTOCGIIRBIS,'),
                  '?C21COM=2&I21DBN=',&uf('+D'),
                  '&P21DBN=',&uf('+D'),
                  '&Z21ID=GUEST',
                  '&Image_file_name=',&uf('+3E',g1),                                
                  '&IMAGE_FILE_DOWNLOAD=0'
                  ),
            else
               &uf('+7W3#',
                  &uf('+3E',g1)
                  ),
            fi,                                                          

            break
         fi,                       
      fi),
   fi,
fi,

if g3 = '' then
   if p(v955^a) then 
      &uf('+7W3#',&uf('IMAIN,PATHTOCGIIRBIS,'),
         '?C21COM=7&I21DBN=',&uf('+D'),
         '&P21DBN=',&uf('+D'),
/*         '&Z21ID=',&uf('+3E',&unifor('Av2225#1')), /* не фиксировать в базе обращение к тексту при показе обложки
         '&Image_file_name=',&uf('+3E',v955^a),
         '&Image_file_mfn=',f(val(MFN),0,0),
         '&FILE_PAGE=1'
         ),
   fi,
fi,

if g3 = '' then
   &uf('+7W3#',&uf('IMAIN,PATHTOHTTPIRBIS,'),
      'images/oblogka.png'),
fi,
if (&uf('IMAIN,PATHTOHTTPIRBIS,')<>'') and (g3<>'') then 
'<IMG style="float:left; margin:10px; width:120px;" SRC="'g3,'">',
fi,