0
0
0
Задание:
0
DEL
991
*


ADD
991

'^A1^B1'

// 10.1 проверка записей каталога с удаление
//13 опрос об удалении повторений, не прошедших контролль
// 991^A - удалять повторение в случае отсутствия конт-та
IF
if p(v691) then '1' fi
DEL
1691
*


ADD
1691

(v691/)

// для признаков удаления 
DEL
112
*


DEL
111
*


ADD
111

'0'

//-------------------------------------- цикл по полям 691
REPEAT
REP
111
1
f(val(v111)+1,0,0)

IF
if &uf('Av1691^I#1')='' then '1' fi
PUTLOG
'Нет идентификатора дисциплины ',&uf('Av1691^D#1'),' MFN=',f(val(mfn),0,0),' (',v111,')'
FI
ADD
112

'0'

IF
if &uf('Av1691^I#1')<>'' then '1' fi
// есть ли запись дисциплины с идентификатором
IF
if Val(&uf('JVUZ,IDD=',&uf('Av1691^I#1')))<=0 then '1' fi
PUTLOG
'Нет дисциплины с идентификатором ',&uf('Av1691^I#1'),' MFN=',f(val(mfn),0,0),' (',v111,')',,if val(v991^A)=1 then ' - повторение удалено' fi
REP
112
L
'1'

FI
// проверяю запись VUZ
//-----------------------------------------
IF
if val(&uf('JVUZ,?',if &unifor('Av1691^a#1')<>'' then &unifor('Av1691^a#1'),'-' fi,,if &unifor('Av1691^n#1')<>'' then &unifor('Av1691^n#1'),'-' fi,,if &unifor('Av1691^c#1')<>'' then &unifor('Av1691^c#1'),'-' fi,,if &unifor('Av1691^v#1')<>'' then &unifor('Av1691^v#1'),'-' fi,,if &unifor('Av1691^o#1')<>'' then &unifor('Av1691^o#1'),'-' fi,,if &unifor('Av1691^f#1')<>'' then &unifor('Av1691^f#1'),'-' fi))<=0 then '1' fi 
PUTLOG
'Нет записи VUZ по связке ',,,,,,&uf('Av1691^A#1'),'-',&uf('Av1691^N#1'),'-',&uf('Av1691^C#1'),'-',,&uf('Av1691^V#1'),'-',,,&uf('Av1691^O#1'),'-',,&uf('Av1691^F#1'),'-',,,,,,,,' MFN=',f(val(mfn),0,0),' (',v111,')',,if val(v991^A)=1 then ' - повторение удалено' fi
REP
112
L
'1'

FI
FI
DEL
1691
1


UNTIL
if p(v1691) then '1' fi
//----------------------------------------
IF
if val(v991^A)=1 then '1' fi
// удаляю повторения
DEL
691
F
(v112/)

FI
//--------------- проверка и удаление на дублетность полей 691
DEL
1691
*


ADD
1691

mpu,(v691/)

DEL
2691
*


REPEAT
ADD
2691

if a(v2691) then &uf('Av1691#1') else if rsum((if p(v1691) then if  &uf('+97',v1691^I)=&uf('Av2691^I#1') and &uf('+97',v1691^S)=&uf('Av2691^S#1') and &uf('+97',v1691^B)=&uf('Av2691^B#1') and &uf('+97',v1691^K)=&uf('Av2691^K#1') and &uf('+97',v1691^L)=&uf('Av2691^L#1') and &uf('+97',v1691^A)=&uf('Av2691^A#1') and &uf('+97',v1691^V)=&uf('Av2691^V#1') and &uf('+97',v1691^O)=&uf('Av2691^O#1')  and &uf('+97',v1691^C)=&uf('Av2691^C#1')  and &uf('+97',v1691^N)=&uf('Av2691^N#1')  and &uf('+97',v1691^F)=&uf('Av2691^F#1')  and v1691^G: &uf('Av2691^G#1') then '1,' fi fi))=0 then &uf('Av1691#1') fi fi

DEL
1691
1


UNTIL
if p(v1691) then '1' fi
IF
if val(&uf('+N691'))>val(&uf('+N2691')) then '1' fi
PUTLOG
'Имеются дубли поля 691. MFN=',,f(val(mfn),0,0),,,if val(v991^B)=1 then ' - удалены' fi
FI
IF
if val(v991^B)=1 then '1' fi
DEL
691
*


ADD
691

(v2691/)

FI
DEL
111
*


DEL
112
*


FI